---

當初林北剛回鍋想要寫發現版上資料真的都太老了

現在這個徵文主題真的很棒

可是都還沒有人發文

就讓林北打個先鋒吧

希望拋磚引玉

更多高手分享好用的巨集


因為林北沒有玩很多職業

這篇主要根據痛術來作範例

希望大家應用到自己的職業有更好的範例也上來分享一下


不會上色還請多多包涵



















一、常用指令

設定巨集圖示時，如果選擇？圖案
巨集中加入
#showtooltip 法術名稱
會自動對應該法術或者物品的圖示


/cast
說明：放法術，後面接法術名稱

範例：/cast 暗影箭


/castsequence [<條件選項>] reset=<#>/target/combat <法術1>, <法術2>, <法術3>
說明：允許你在連續點擊某個巨集時，將其中定義的一系列法術逐個施放
      當你第一次點擊這個巨集時，它施放列表中的第一個法術

範例：/castsequence 痛苦動盪,痛苦災厄,腐蝕術



/use
說明：使用物品、飾品、裝備

範例：/use 部落徽記
      /use 13 (使用裝備13，就是飾品1，這樣寫的好處是你換飾品一樣可以用)


/stopmacro
說明：強制停止巨集


/castrandom
說明：隨機施放下列法術

範例：/castrandom 西風之龍,北風之龍,東風之龍,南風之龍


/p /s /g .....
說明：各種頻道發話
範例：/p 我要開怪了!




















二、條件判斷指令


格式： /常用指令 [條件1] 法術或物品名稱; [條件2]法術或物品名稱 ...

條件用","分開代表AND   用"/"分開代表OR
";"代表ELSE，條件不符合則執行";"之後的動作
條件前面+"no"則代表條件的相反


[help]
說明：目標是否為友善

範例：/cast [help] 黑暗意圖
      目標為友善則施放黑暗意圖，否則不做任何事

      /cast [help] 黑暗意圖;腐蝕術
      目標為友善則施放黑暗意圖，否則施放腐蝕術


[harm]
說明：目標是否為敵人，與上面剛好相反而已

範例：/use [noharm] 靈魂石
      /stopmacro [harm]


[combat]
說明：玩家本身是否在戰鬥中

範例：/use [combat] 亞麻繃帶
      /cast [nocombat] 靈魂收割
      如果就戰鬥中使用繃帶，不再戰鬥中就施放靈魂收割


[stealth]
說明：玩家本身是否潛行
範例：/cast [stealth] 伏擊; 背刺
      玩家處於潛行時施放伏擊，否則就背刺


[pet]
說明：是否有寵物

範例：/cast [pet] 靈魂鏈結;靈魂炙燃
      /stopmacro [pet]
      /cast 召喚惡魔獵犬
      有寵物則施放靈魂鏈結，否則施放靈魂炙燃並且召喚惡魔獵犬

      /cast [pet:虛空行者] 犧牲; [pet:魅魔] 誘惑; [pet:惡魔獵犬] 吞噬魔法
      攜帶各種寵物時施放不同技能


[stance]
說明：有些職業有不同的姿態

      戰士：1. 戰鬥 2. 防禦 3. 狂暴
      牧師：1. 暗影形態
      德魯伊：1. 熊 2. 水棲 3. 貓 4. 旅行 5. 梟獸/樹
      盜賊：1. 潛行

範例：/cast [nostance] 熊形態
      如果沒有在一個形態下，則變形到熊形態

      /cast [stance:1] 壓制; [stance:2] 破甲; [stance:3] 旋風斬
      在戰鬥姿態下施放壓制
      防禦姿態下施放破甲
      狂暴姿態下施放旋風斬

PS.姿態這邊我比較不熟，期待其他高手補充


[target]
說明：檢查目標
      player = 玩家本身
      target = 目標
      targettarget = 目標的目標
      focus = 專注目標
      party1 = 隊員#1 即 F2
      party2 = 隊員#2 即 F3
      party3 = 隊員#3 即 F4
      party4 = 隊員#4 即 F5
      party1target = 隊員#1的目標
      party2target = 隊員#2的目標
      party3target = 隊員#3的目標
      party4target = 隊員#4的目標

範例：/use [target = player] 亞麻繃帶
      把目標設成自己並且使用繃帶

      /cast [help] 快速治療; [target=targettarget] 快速治療
      如果目標是友善的，則向他施放快速治療
      否則向目標的目標施放快速治療

      /cast [target = focus] 恐懼術
      對專注目標施放恐懼術


[exists]
說明：目標是否存在

[dead]
說明：目標是否死亡

範例：/focus [target=focus,noexists] target; [target=focus,dead] target
      /cast [target=focus,harm] 恐懼術
      /stopmacro [noharm]
      /p %t 被我嚇得內牛滿面
      若專注目標不存在或死亡則將當前目標設定為專注目標
      若專注目標為敵人則施放恐懼術


[button]
說明：檢查用哪個按鍵點巨集
      1.滑鼠左鍵
      2.滑鼠右鍵
      3.滑鼠中鍵
      4.滑鼠4號鍵
      5.滑鼠5號鍵

範例：/cast [nobutton:2] 虛弱詛咒;疲勞詛咒
      左鍵施放虛弱詛咒，右鍵施放疲勞詛咒

      /cast [button:1] 靈魂炙燃
      /cast 惡魔法陣:傳送
      左鍵的話施放靈魂炙燃，然後施放惡魔法陣:傳送
      右鍵的話直接施放惡魔法陣:傳送
      (這邊術士的靈魂炙燃會有就施放，沒有就不放)

      /cast 靈魂炙燃
      /cast [nobutton:2] 召喚魅魔;召喚惡魔獵犬
      施放靈魂炙燃，並且用左鍵召喚魅魔或者用右鍵召喚惡魔獵犬


[channeling]
說明：是否正在channel需要channel的法術

範例：/cast [nochanneling:吸取靈魂] 吸取靈魂
      不是channel吸取靈魂時施放吸取靈魂
      (用來避免還沒channel完就提早施放而浪費魔)

      /cast [nobutton:2] 靈魂炙燃
      /cast [nochanneling:吸取生命] 吸取生命
      不是左鍵的話施放靈魂炙燃，並且不是channel吸取生命時施放吸取生命
      左鍵的話則，不是channel吸取生命時施放吸取生命


[equipped]  (裝備可以用物品編號)
說明：檢查身上裝備

範例：/cast [equipped:雙手劍] 致死打擊; 英勇打擊
      當你裝備著雙手劍時施放致死打擊
      否則施放英勇打擊

      /equip [noequipped:魚竿] 魚竿
      /cast [equipped:魚竿] 釣魚
      當你沒裝備魚竿的時候裝備魚竿
      當你有裝備魚竿的時候施放釣魚


[modifier]/[modifier:shift|ctrl|alt]
說明：檢查某個鍵是否被按下

範例：/cast [modifier:ctrl] 虛弱詛咒; [modifier:shift] 疲勞詛咒;
[modifier:alt] 語言詛咒
      CTRL+左鍵施放虛弱詛咒
      SHIFT+左鍵施放疲勞詛咒
      ALT+左鍵施放語言詛咒



[mounted]
說明：是否騎馬

[swimming]
說明：是否游泳

[flying]
說明：是否飛行

[indoors]
說明：檢測是否在室內

[outdoors]
說明：檢測是否在室外

[flyable]
說明：是否可以飛行

範例：/castrandom [noflyable] 恐懼戰馬,哥布林渦輪機動車
      /castrandom [flyable] 西風之龍,北風之龍,南風之龍,東風之龍



三、有趣巨集分享

隨機叫出一隻小夥伴並且隨機發話

/run CallCompanion("CRITTER", random(GetNumCompanions("CRITTER")))
/script s={"大喊:就決定是你了!皮卡稱!","拿出一個好像很好玩的東西!","背後好像有
奇怪的東西跟著..."};
/script SendChatMessage(s[math.random(getn(s))], "Emote");

第一行當然也可以用/castrandom放上自己喜歡的夥伴就好
第二行的字可以自己改，或者增加更多句子
第三行的"Emote"是用/e發話，可以自己改成其他種





這些指令都是比較基礎的

希望有幫到大家!


--
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 114.39.102.209
※ 編輯: CarPusher       來自: 114.39.102.209       (06/03 10:41)

/cast [target=mouseover] 腐蝕術
對滑鼠指到的目標施放腐蝕術
不會更改你選的目標喔!
好用的忘記講XD


我講dead跟exsists那邊有耶
還是那不是你要問的？

※ 編輯: CarPusher       來自: 114.39.102.209       (06/03 11:05)

--